****
* MODELO PARA EL CHIP CD4007
* Basado en:
* 	Library of Miscellaneous Analog Models
*	Copyright Cadence Design Systems, Inc. 2002 All Rights Reserved.
*
* Ajustado para el curso Electronica 1, FING, UdelaR
* ver. 2014
*----------------------------------------------------------------------------
************************* ADVERTENCIA *******************************
* Este subcircuito utiliza el modelo para transistores MOS mas basico
* disponible en los simuladores SPICE.
* No modela de forma correcta el comoportamiento de los dispositivos
* en la zona de inversion moderada o debil (VGS-Vt < 100 ... 200 mV)
* Tampoco modela de forma correcta una larga lista de efectos de 2do
* orden como por ejemplo: saturacion de velocidad, DIBL, efectos de
* canal corto, etc.
* Por lo tanto se recomienda utilizar con precaución y analizar
* los resultados de las simulaciones con una actitud critica (o sea,
* aun mas critica de lo usual).
* En lo que refiere al Laboratorio 3 del curso, se recomienda el uso
* de este modelo solo para la parte 3 (Amplificador CMOS), ya que en
* las partes 1 y 2 los resultados pueden variar sensiblemente con
* respecto a las medidas y/o las cuentas a mano.
************************* ADVERTENCIA *******************************
*-----------------------------------------------------------------------------

*14-pin DIP: pin#1  #2  #3  #4  #5  #6  #7  #8  #9  #10 #11 #12 #13 #14
*                |   |   |   |   |   |   |   |   |   |   |   |   |   |
.subckt CD4007 p01 p02 p03 p04 p05 p06 p07 p08 p09 p10 p11 p12 p13 p14

* BE SURE to keep pin #14 at the most positive potential w.r.t any other pin!
* BE SURE to keep pin # 7 at the most negative potential w.r.t any other pin!

  m_N1 p08   6 p07 p07 nch	; device N1
  m_N2 p05   3 p04 p07 nch	; device N2
  m_N3 p12  10 p09 p07 nch	; device N3

  m_P1 p13   6 p14 p14 pch	; device P1
  m_P2 p01   3 p02 p14 pch	; device P2
  m_P3 p12  10 p11 p14 pch	; device P3

* Input protection circuits

  rx03 p03   3 r_zap 1		; input protection on pin #3
  dx3p p03 p14 d_zap
  di3p   3 p14 d_zap
  di3n p07   3 d_zap

  rx06 p06   6 r_zap 1		; input protection on pin #6
  dx6p p06 p14 d_zap
  di6p   6 p14 d_zap
  di6n p07   6 d_zap

  rx10 p10  10 r_zap 1		; input protection on pin #10
  dx1p p10 p14 d_zap
  di1p  10 p14 d_zap
  di1n p07  10 d_zap

  d1 p07 p14 d_body		; supply protection diode

* MOS characteristics

.model nch nmos(Level=1 Tox=300n Kp=44.3u W=144u L=8u Vto= 1.31
+		Lambda=50m GAMMA=1.8 PHI=0.6 Cbd=4p Cbs=4p Cgdo=1.7n Cgso=1.7n Rs=1 Rd=1)

.model pch pmos(Level=1 Tox=300n Kp=15.5u W=328u L=8u Vto=-1.53
+		Lambda=50m GAMMA=0.8 PHI=0.6 Cbd=8p Cbs=8p Cgdo=1.7n Cgso=1.7n Rs=1 Rd=1)

.model r_zap  res(r=1.73K)
.model d_zap  D(Is= 1p Rs=1 N=1 Xti=3 Eg=1.11 Cjo=.01p M=0 Bv=20 Ibv=.1u)
.model d_body D(Is=15n Rs=1 N=1 Xti=3 Eg=1.11 Cjo=10p M=.5 Vj=.75
+		Fc=.5 Isr=.15n Nr=2 Bv=20 Ibv=100u)
.ends

*End of CD4007 model